パソコン活用研究5番街（Visual Basic、Excel(VBA)、BASIC　プログラミング研究）

キーボード入力

キーボードからの入力に関する命令、関数というと、INPUT, LINE INPUT, INKEY$, INPUT$,
KEY, ON KEY GOSUBといったところでしょうか。

INPUT および INKEY$の基本的な使い方については、ＢＡＳＩＣ超基本　、　ＢＡＳＩＣ超基本２　にて
とりあげました。また、リアルタイムゲーム作制のための実践的なキーボード入力に関するノウハウ
は、リアルタイムキースキャン　でとりあげております。
ここでは、上記でとりあげた以外のキーボード入力に関する基本的なノウハウをまとめてみました。

１　キー入力待ちはＩＮＰＵＴ＄（ｎ）　が便利

ＩＮＰＵＴ，ＩＮＰＵＴ＄，ＩＮＫＥＹ＄ の違いはよろしいでしょうか。

例えば、INPUT$(3) とすると、３文字入力されるまで入力待ちします。
使い途といしては、いったんＧＡＭＥが終了して、もう一回やるかどうかを、"y" か "n"で答えさせるような
場合に一番適しているでしょう。

簡単な例をあげておきます。
＜Ｉｎｐｕｔ０．ｂａｓ＞

10 a$=input$(1)
20 if a$="Y" or a$="y" then goto 100　　
30 if a$="N" or a$="n" then goto 200
40 goto 10
100 print "Contine":goto 10
200 print "end": end

２　キー入力による条件分岐　INSTRの使用

先ほどでてきた、 ＜Ｉｎｐｕｔ０．ｂａｓ＞ では、入力されたキーを IF文で判定して、それぞれの分岐先に
とばしていました。入力されるキーの種類がこれぐらいなら、まあいいでしょうが、５種類ぐらいのキーを
使い分けるゲーム、といったことになると、IF 文を５個並べることになります。そういう場合に、昔から
これぞＢＡＳＩＣの定石といわれてきたのが、INSTR関数 の利用です。
簡単に INSTR　の書式をあげておきます

以下に＜ｉｎｐｕｔ０．ｂａｓ＞をINSTR で書き換えたものをあげます。

これぐらいのコードを書くと、素人のＢＡＳＩＣプログラマとしては、「ちっとはＢＡＳＩＣ知ってるな」とかコメント
されたものです。（大昔、アマチュアのＢＡＳＩＣプログラムの雑誌への投稿が盛んだった時代の話。
いつかって？ウーム、パソコン進化の歴史からすると、縄文、弥生時代とでもいうべきか）

３　INSTRは早いか

ＢＡＳＩＣの場合は、やっぱり処理スピードが早いかどうかもきになります。
INSTR関数をつかって「お主、少しはやるじゃねーか」と言われても、スピードダウンになったんじゃ
お話になりません。それで、いちおう処理スピードについても検証してみました。

＜ｉｎｐｕｔｓｐ０．ｂａｓ＞

10 width 80,20
20 cls
25 a$=""
30 t=val(right$(time$,2))
40 for i=0 to 1000
50 if a$="Y" or a$="y" then gosub 200　　　　
55 if a$="N" or a$="n" then gosub 210 
60 next i
100 t1=val(right$(time$,2))
110 if t1<t then t1=t1+60
120 print t1-t :end
130 ' 22
200 return
210 return

10 'WIDTH 80, 20
20 CLS
25 a$ = ""
30 t = VAL(RIGHT$(TIME$, 2))
40 FOR i = 0 TO 300000
50 IF a$ = "Y" OR a$ = "y" THEN GOSUB 200　　　
55 IF a$ = "N" OR a$ = "n" THEN GOSUB 210
60 NEXT i
100 t1 = VAL(RIGHT$(TIME$, 2))
110 IF t1 < t THEN t1 = t1 + 60
120 PRINT t1 - t: END
130 ' 22
200 RETURN
210 RETURN

＜ｉｎｐｕｔｓｐ１．ｂａｓ＞
IF文を１つにしてみました

10 width 80,20
20 cls
25 a$=""
30 t=val(right$(time$,2))
40 for i=0 to 1000
50 if a$="Y" or a$="y" then gosub 200 
60 next i
100 t1=val(right$(time$,2))
110 if t1<t then t1=t1+60
120 print t1-t :end
130 ' 13  (for  nextループは５秒くらい)　　
200 return
210 return

10 'WIDTH 80, 20
20 CLS
25 a$ = ""
30 t = VAL(RIGHT$(TIME$, 2))
40 FOR i = 0 TO 300000
50 IF a$ = "Y" OR a$ = "y" THEN GOSUB 200
60 NEXT i
100 t1 = VAL(RIGHT$(TIME$, 2))
110 IF t1 < t THEN t1 = t1 + 60
120 PRINT t1 - t: END
130 ' 18  (for__ next 13seconds)　　　　　　　　
200 RETURN
210 RETURN

＜ｉｎｐｕｔｓｐ２．ｂａｓ＞
INSTR関数使用

10 width 80,20
20 cls
25 a$=""
30 t=val(right$(time$,2))
40 for i=0 to 1000
50 on instr("YyNn",a$) gosub 200,200,210,210　
60 next i
100 t1=val(right$(time$,2))
110 if t1<t then t1=t1+60
120 print t1-t :end
130 ' 15.5
200 return
210 return

10 ' WIDTH 80, 20
20 CLS
25 a$ = ""
30 t = VAL(RIGHT$(TIME$, 2))
40 FOR i = 0 TO 300000
50 ON INSTR("YyNn", a$) GOSUB 200, 200, 210, 210　　　
60 NEXT i
100 t1 = VAL(RIGHT$(TIME$, 2))
110 IF t1 < t THEN t1 = t1 + 60
120 PRINT t1 - t: END
130 ' 16
200 RETURN
210 RETURN

ええとですね、これぐらい単純なプログラムだと、For ... Next　のループ自体にかかる時間が無視できない
レベルにあるので、For ... Next ループ自体にかかる時間を考慮して下表のようにまとめてみました。

人それぞれ、いろんな評価があるでしょうが、実用上 INSTRを使うことは速さの点でも有益だと
言えましょう。ことにＱＢＡＳＩＣでの利用価値は高いと言えます。

蛇足ながら、Ｎ８８互換ＢＡＳＩＣ と ＱＢＡＳＩＣ でループの回数は３００倍違います。ご注意。


４ LINE INPUT の利用

INPUTで文字列を入力する場合、カンマ（,）は、区切り記号として使うので、データとして入力できません。
カンマもデータとして入力したい場合は、LINE INPUTを使えばＯ．Ｋ．です。
LINE INPUT　はリターンキーが押されるまでの文字列を全てデータとして入力します。
（本来、LINE INPUTはファイルからの読み込みの方でよく使われる）

以下に、入力された文字列を、カンマのところでばらばらに区切って表示するプログラムを
あげておきます。他に、MID$, RIGHT$, LENなど文字列関連の関数も使った例になってますので
Ｖｅｒｙ Ｓｈｏｒｔ な中に、濃い内容がつまったプログラムです。ビタミン剤のようなプログラムですから、
ＢＡＳＩＣはじめたバカリダヨーという人は、じっくり味わって消化して下さい。　　
＜ＬＩＮＰＵＴ．ｂａｓ＞

5 position=1:p=1
10 line input a$
20 while p
30 p=instr(position,a$,",")
35 if p=0 then goto 60
40 print mid$(a$,position,p-position)
50 position=p+1
60 wend
70 print right$(a$,len(a$)-position+1)　　　

ＱＢＡＳＩでの実行結果

５　入力されたキーのアスキーコードの取得

入力されたキーのアスキーコードを利用したい場合というのがあります。
例えば、[Esc] キー や -> のような矢印キーの入力の判定といった場合です。
このような時は、ASC関数を使います。

下のプログラムは何をやってるかと言うと、テキストファイルを読み込んで、画面に表示されない特殊キー
は［　　］内にアスキーコードを表示するというプログラム。７５行に注目。
それから、８０行は、読み込んだデータがラインフィード（ＬＦ　アスキーコード１０）だったら改行させている。
MS-DOSのTYPE コマンドにプラスαの機能をつけた感じのもの。
＜ＫＴＹＥＰＥ．ｂａｓ＞　ＱＢＡＳＩＣ用

10 cls:key(1) on
20 on key(1) gosub 120  'Ｎ８８互換ＢＡＳＩＣ用には on key gosub 120 でよい　　
30 on error goto 100
40 input "File Name :",file$
50 open file$ for input as #1
60 while not(eof(1))
70 a$=input$(1,#1)
75 if asc(a$)>31 then print a$; else print "["+str$(asc(a$))+"]";　　　　
80 if asc(a$)=10 then print
90 wend
100 close
110 key(1) off:end
120 return 100

これも、ＱＢＡＳＩＣの実行例をいちおうつけときます。自らを読みこんでみました。

６　KEY, ON KEY
プログラム実行中に、キーを押して、割り込みをかけたい場合に使います。
上述の＜ＫＴＹＰＥ．ｂａｓ＞の１０、２０、１１０行目をみて下さい。
上述のプログラムでは、長いファイルを読みこんでいる時に、もう途中であきた、中断したいというケース
を想定して、ファンクションキー１（Ｆ１）を押せば、プログラムが終了するようにしてあります。
それが、１０、２０、１１０行目です。

KEY ON, KEY OFF は割り込みの許可、解除をします。
プログラム終了前に必ず KEY OFFする必要があります。さもないと、本来のファンクションキーの
機能がつかえないままとなります。

ON KEY GOSUB　割り込みルーチンの開始行の定義をしますが、Ｎ８８互換ＢＡＳＩＣ ｆｏｒ ＷＩＮ と
ＱＢＡＳＩＣ で若干書式と機能が異なります。

Ｎ８８互換ＢＡＳＩＣ　ｆｏｒ ＷＩＮ

ＱＢＡＳＩＣ
ＱＢＡＳＩＣの場合は キー番号が若干異なる。また、KEY( ) ON, OFFでキー番号を省略することは
できないようだ。
キー番号は　１から１０がファンクションキー（これは同じ）、１１が上矢印、１２が左、１３が右、１４が下と
なっている。０を指定すると、全てのキーを指定したことになる。

また、割り込み開始行の定義は、ON KEY(キー番号) GOSUB　という形で、必ずキー番号を指定
する形になる。


＊今回とりあげたプログラムは＜ＫＴＹＰＥ．ｂａｓ＞以外は、Ｎ８８互換ＢＡＳＩＣ ｆｏｒ ＷＩＮ 、ＱＢＡＳＩＣ
ともに共通です。

ＴＯＰ ＰＡＧＥ >Ｂａｓｉｃ活用研究目次