旧ＢＡＳＩＣ

　パソコン活用研究5番街（Visual Basic、Excel(VBA)、BASIC　プログラミング研究）

旧ＢＡＳＩＣ－－ＢＡＳＩＣ(PEEK,POKE)からマシン語へ、メモリーへのアクセス、パソコン探索(QB)

１めもりーについて（基礎）

Ｚ８０，６８０９といった８ビットＣＰＵがアクセスできたメモリーは、００００Ｈ～ＦＦＦＦＨ（Ｈは１６進数
を表す）。すなわち、６４Ｋバイトです。ＰＥＮＴＩＵＭの基本？となった８０８６という１６ビットＣＰＵが
アクセスできたのは、０００００Ｈ～ＦＦＦＦＦＨ、すなわち１Ｍバイトです。
８ビットＣＰＵの場合、メモリーのアドレス（番地）は単純に３４５５Ｈのように指定すればよく、例え
ば、アセンブラで、ＪＭＰ３０００Ｈ（６８０９アセンブラのジャンプ命令）というのは、３０００Ｈ番地
へジャンプせよという、ことでした。

いっぽう、８０８６では番地の指定には、オフセットアドレス、セグメントアドレスという２つの
アドレスで指定されることとなりました。指定の仕方は、
番地＝（セグメントアドレス＊１６）＋オフセットアドレス
ということになります。（セグメントアドレス、オフセットアドレスともに００００ＨからＦＦＦＦＨまで
となります。）
面倒なことですが、Ａ５０００Ｈのようには直接指定できません。

８０８６のＪＭＰ命令は、ＪＭＰオフセットアドレス （ＪＭＰ５６００Ｈなど）
という記述になります。
今仮に、セグメントアドレス（以下ＳＥＧと略す）が００００Ｈの時に、ＪＭＰ１０００Ｈということは、
実際の番地は、０Ｈ＊１６＋１０００Ｈ＝１０００Ｈとなります。
ＳＥＧが２０００ＨでＪＭＰ１０００Ｈなら
実際の番地は、２０００Ｈ＊１６＋１０００Ｈ＝２００００Ｈ＋１０００Ｈ＝２１０００Ｈとなります。
（＊１６進数で２０００Ｈ＊１６（＝１０Ｈ）は２００００Ｈです。）

ＳＥＧを指定するには、セグメントレジスタというレジスタを使います。８０８６では、主に
ＣＳ（コードセグメント）・・・実行コードのあるセグメントを指定する。
ＤＳ（データセグメント）・・・データのあるセグメントを指定する。
というセグメントレジスタを使います。

さて、賢明な方はお気づきの通り、この番地の指定の仕方の場合、同じ番地を指定するのに
いくとおりでもやり方があることになります。例えば、１００Ｈを指定したい場合
ＳＥＧ＝１０Ｈオフセットアドレス＝０Ｈでも、ＳＥＧ＝０Ｈオフセットアドレス＝１００Ｈ
でも良いわけです。従って、下手にＣＳ，ＤＳを設定すると、データ領域とコード領域が重なって、
データでマシン語コードをつぶして、暴走ということもありえるわけです。

ちなみに、２８６、３８６、４８６、ＰＥＮＴＩＵＭでは、１Ｍバイト以上のメモリーをアクセスできるよう
になりましたが、メモリーの番地の指定は複雑になり、簡単にはアクセスできなくなりました。
ここでは説明いたしません。

２ＰＥＥＫ，ＰＯＫＥ

Ｂａｓｉｃである程度プログラムできるようになると、なんとなく機械語（＝マシン語＝ＣＰＵが直接
解釈できるコード）でコーディングしたくなるものです。（というのは昔の話だろうか）
今は、Ｃ／Ｃ＋＋をやりたくなるというのが定石かな。
ま、それはいいとして、むかーし「準備なしに機械語を始めると、奇怪語？に遭遇して、カルチャーショックをうけますよ」なんて冗談がありましたが、いきなりアセンブラというのは・・・、という
ご要望にこたえて、とりあえずＢＡＳＩＣから機械語へとアプローチしてみましょう。
なお、ＢＡＳＩＣとはいっても、各種ありますが、WINDOWS上で再現可能ということで、主として
ＱＢＡＳＩＣを使って、話を進めます。

第１部のメモリーの話はＯ．Ｋ．でしょうか。あと、機械語を覗くのに必要な基礎知識として、
ＨＥＸ＄，ＶＡＬをおさらいしておきましょう。
ＨＥＸ＄・・・１０進数を１６進数の文字変数に変換する関数です。ＨＥＸ＄（１７）＝１１
ＶＡＬ・・・・１６進数（文字列）を１０進数の数値変数に変換する関数。ＶＡＬ（”＆Ｈ１１）＝１７

PEEK （アドレス）
メモリーの値を読み出す関数です。
Ａ＝ＰＥＥＫ（＆Ｈ４０００）とすると、変数Ａに＆Ｈ４０００番地の値が読みこまれます。
ただし、８ビットＣＰＵのＢａｓｉｃの場合は、この通りですが、上述の通り、８０８６以上
のパソコンの場合は、DEF ＳＥＧ＝セグメントアドレス、ＰＥＥＫ（オフセットアドレス）という
指定の仕方になります。
（なお、Ｎ８８互換ＢＡＳＩＣｆｏｒＷｉｎでは、ＰＥＥＫ，ＰＯＫＥはサポートしてません。
Ｗｉｎｄｏｗｓ上で直接番地を指定してメモリーの値を読む、というのはできないと思って
下さい。）

＜Ｎ８８ＢＡＳＩＣ（８６）用＞
１０ＤＥＦＳＥＧ＝＆Ｈ５０００
２０Ａ＝ＰＥＥＫ（＆Ｈ５００）
３０ＰＲＩＮＴＨＥＸ＄（Ａ）
というプログラムでセグメントアドレス＆Ｈ５０００、オフセットアドレス＆Ｈ５００番地の値が
１６進数で表示できます。ＱＢＡＳＩＣでも行番号をとれば、これでＯ．Ｋ．

それでは、まとめてメモリーを覗くプログラムを作ってみましょう。
基本的には

＜Ｎ８８ＢＡＳＩＣ（８６）用＞Ｑｂａｓｉｃは行番号をとればＯ．Ｋ．
１０ＤＥＦＳＥＧ＝＆Ｈ１０００　　　’ここにはいろんなセグメントアドレスを書く
２０ＦＯＲＩ＝０ＴＯ＆ＨＦＦＦＦ
３０ＰＲＩＮＴＨＥＸ＄（ＰＥＥＫ（Ｉ））＋” ”；
４０ＮＥＸＴ
でＳＥＧ＝＆Ｈ１０００から６４Ｋバイト分（＆ＨＦＦＦＦ）表示するプログラムになります。
しかし、これでは、ダッーと表示していってしまい、見にくいので、少し工夫したプログラム
を以下にのせます。

＜ＱＢＡＳＩＣ用＞

'Memory Dump of Qbasic written by Kasai
DIM q(20)
st:
CLS
PRINT "Memory Dump of Qbasic written by Kasai"
PRINT "64 KB memory dump"
PRINT "Press 1 Key to suspend      Press 2 Key to stop"
INPUT "SEGment address : ", s$
DEF SEG = VAL("&h" + s$)
PRINT "    + 0  1  2  3  4  5  6  7  8  9  A  B  C  D  E  F"
FOR i = 0 TO &HFFF
segadd = (VAL("&h" + s$) + i) * 16
PRINT RIGHT$("0000" + HEX$(segadd) + ":", 6);
FOR j = 0 TO 15
q(j) = PEEK(i * 16 + j)
PRINT RIGHT$("0" + HEX$(q(j)) + " ", 3);
NEXT j
FOR j = 0 TO 15
IF q(j) < &H20 THEN ch$ = " " ELSE ch$ = CHR$(q(j))
PRINT ch$;
NEXT j
PRINT

e$ = INKEY$
IF e$ = "1" THEN
PRINT "Hit return key to start again"
INPUT r$
PRINT "    + 0  1  2  3  4  5  6  7  8  9  A  B  C  D  E  F"
END IF
IF e$ = "2" THEN EXIT FOR

NEXT i
PRINT "Continue C    End  E"
L1:
w$ = INPUT$(1)
IF w$ = "C" THEN GOTO st
IF w$ = "E" THEN END ELSE GOTO L1

最初にセグメントアドレスを聞いてきますので、セグメントアドレスを入力して下さい。
ダッーと６４Ｋバイト表示していきますので、途中でいったん停止したければ、１を押して
下さい。再開はリターンキーです。２を押すと終了です。
このＱＢＡＳＩＣによるプログラムは、ＭＳ－ＤＯＳプロンプト、ＭＳ－ＤＯＳモードで動きます
ので、いろいろなアドレスを表示させてみて下さい。
ただし、WINDOWSにおける、ＭＳ－ＤＯＳプロンプトは、ＭＳ－ＤＯＳのエミュレート（ＭＳ－ＤＯＳ
のふりをしている）です。上述のように、Ｗｉｎｄｏｗｓは３２ビットＣＰＵで動いてますので、
実際のアドレス指定はもっと複雑です。このプログラムで、ＳＥＧとオフセットアドレスの指定
だけで、ＰＥＥＫ関数で読んでいるメモリーは、Ｗｉｎｄｏｗｓが、ＭＳ－ＤＯＳのフリをして、
うまいこと機能させているというわけです。（ま、とりあえずこれでよしとしましょう）

もちろん、フロッピーから純然たるＭＳ－ＤＯＳや起動ディスクから立ち上げても動きます。

実際に、ＰＥＥＫ関数を使った簡単なプログラム例。
以下のプログラムはＰＣ２００１のメモリーを読んで、ＲＳ２３２Ｃで外部にデータを送信する
プログラムです。実際、筆者はこれで、ＰＣ２００１のメモリーを読んで、Ｗｉｎｄｏｗｓ機に
データ転送し、Ｗｉｎｄｏｗｓ機上で組んだＰＣ２００１用ディスアセンブラで、ＰＣ２００１の
ＲＯＭ解析や、ＰＣ２００１中間コード変換プログラムで、中間コード＝＝＞テキストプログラム
変換などやりました。（参考ＲＳ２３２Ｃプロジェクト）

メモリー上のバイナリデータを文字データに変換してＲＳ２３２Ｃに送信するぷろぐらむ。
メモリー上の＆ＨＥ０００から＆ＨＥ３００までのデータを送信します。
＆ＨＥ０００からはＢＡＳＩＣプログラムが中間コードの形で入ってます。

10 Term J,0,4 ’データ長８ビット、パリティ無し、１２００ボー
20 For I=&HE000 to &HE300
30 D=Peek(I) ’メモリーのバイナリデータを読む
40 Print %1,HEX$(D); ’文字型に変換してＲＳ２３２Ｃから送信
50 next

ＰＯＫＥ

ＰＯＫＥアドレス、数値
ＰＥＥＫ関数でメモリーを読みましたが、逆にメモリーに書き込むのが、ＰＯＫＥ関数です。

例えば、
ＳＥＧ＝＆Ｈ７０００
ＰＯＫＥ＆Ｈ３００，＆Ｈ２１
と書けば、ＳＥＧ＝＆Ｈ７０００，オフセットアドレス＆Ｈ３００に＆Ｈ２１を書きこみます。
ＰＲＩＮＴＨＥＸ＄（ＰＥＥＫ（＆Ｈ３００））
で逆に読み出して確かめて見てください。

ただし、ＰＯＫＥで書き込む時に、システムが使用している領域に変な数を書き込んでしまう
とコンピューターが暴走してしまいますので、そこらへんは、よくマニュアル等で調べて下さい。

Ｖ－ＲＡＭ書き込み
Ｖ－ＲＡＭのＶは、ＶｉｄｅｏのＶです。すなわち、ＣＲＴに出力するデータがある所です。
昔のパソコンの多くはメインＲＡＭ上の一部をＶ－ＲＡＭとして割り当てていたため、
ＰＯＫＥ関数で直接Ｖ－ＲＡＭにデータを書き込むことにより、画面にデータを出力できました。
こうすると、ＬＯＣＡＴＥＸ，Ｙ：ＰＲＩＮＴ ”＊”というお決まりのやり方より、スピードアップに
なったため、昔のＢＡＳＩＣプログラム（アマチュア作の）でよく使われていました。
そういう技をつかうと、ＢＡＳＩＣプログラマーとして、そろそろ中級かとコメントされたものです。

ＭＳ－ＤＯＳプロンプト、ＭＳ－ＤＯＳモードのメモリーマップ等に関する資料がないため、
試行錯誤でいろいろやってみたところ、ＰＣ／ＡＴ（ＤＯＳ／Ｖ）機のＭＳ－ＤＯＳプロンプト、
ＭＳ－ＤＯＳモードでは＆ＨＣ８０００からがテキストＶ－ＲＡＭのようなので、そこにＰＯＫＥ関数
で書き込むプログラムを作ってみました。（ＰＣ－９８シーリズではだめだと思います）

＜ＱＢＡＳＩＣ＞

DEF SEG = &HB800
st:
CLS
PRINT "V-RAM Access Practice by QBasic"
PRINT "written by Tsuyoshi Kasai"
INPUT "COLOR NO. (smaller than 255)", c
c = c MOD 256
FOR i = 0 TO 256
POKE i * 2, i MOD 256
POKE i * 2 + 1, c
NEXT
PRINT "Once More---(Y/N)"
loop1:
a$ = INKEY$
IF a$ = "Y" THEN GOTO st
IF a$ = "N" THEN END
GOTO loop1

これは、Ｖ－ＲＡＭに直接書き込むことにより、画面に表示させるプログラムです。
実行するとこんな感じです。

さて、Ｖ－ＲＡＭへの書き込みをＰＯＫＥ関数で行うと速い、といいましたが、ついでに
その実験をしてみます。
ＳＡＭＰＬＥ－１は、７９９回ひたすら、ＰＯＫＥでキャラクタを書き込むプログラムです。
ＳＡＭＰＬＥ－２は同じ事を、ＰＲＩＮＴ文でやっています。
プログラム開始と終了時にＴｉｍｅを計測して表示させます。
ＳＡＭＰＬＥ－１とＳＡＭＰＬＥ－２では、筆者のパソコンのＭＳ－ＤＯＳプロンプトでは、
共に、約０．０５秒で大差ありません。ＰＯＫＥを使うことに意味があるのでしょうか。
（筆者の記憶だと、昔のふるーいＢＡＳＩＣではＰＲＩＮＴ文はかなり遅くなったはずだが
まあ、ＢＡＳＩＣの違いでいろいろあるので）

＜ＱＢＡＳＩＣ用＞

ＳＡＭＰＬＥ－１
CLS
DEF SEG = &HB800
t = TIMER
FOR i = 0 TO 799
POKE i * 2 , &H40
NEXT
t1 = TIMER
LOCATE 17, 1
PRINT "time": PRINT USING "##.####"; t1 - t

ＳＡＭＰＬＥ－２
CLS
DEF SEG = &HB800
t = TIMER
FOR i = 0 TO 799
PRINT "h";
NEXT
t1 = TIMER
LOCATE 17, 1
PRINT "time": PRINT USING "##.####"; t1 - t

それでは、キャラクタを移動させるプログラムも試してみます。
ＳＡＭＰＬＥ－３ではＰＯＫＥだけを使っています。ＳＡＭＰＬＥ－４では、同じ事を、ＬＯＣＡＴＥ
とＰＲＩＮＴ　でやっています。
結果はＳＡＭＰＬＥ－３では約０．１秒。ＳＡＭＰＬＥ－４では約０．２秒。
ということで、めでたくＰＯＫＥ　で直接Ｖ－ＲＡＭに書き込む方が速いという結果になりました。
（最近のパソコンでは、画面の書き換えよりキャラクタの移動の方が圧倒的に速いので、
実行しても良く分からないかもしれません。それで、わざとウェイトをかけて遅くしたのが
ＳＡＭＰＬＥ－５です。これで試して見てください。ちなみに筆者のパソコンでは約３分かかります）

ＳＡＭＰＬＥ－３　　

CLS
DEF SEG = &HB800
x = 0
t = TIMER
FOR i = 0 TO 799
POKE x, &H20
POKE i * 2, &H40
x = i * 2
NEXT
t1 = TIMER
LOCATE 17, 1
PRINT "time": PRINT USING "##.####"; t1 - t

ＳＡＭＰＬＥ－４

CLS
DEF SEG = &HB800
x = 1: y = 1
t = TIMER
FOR i = 1 TO 10
FOR j = 1 TO 79
LOCATE y, x: PRINT " ";
LOCATE i, j: PRINT "*";
y = i: x = j
NEXT
NEXT
t1 = TIMER
LOCATE 17, 1
PRINT "time": PRINT USING "##.####"; t1 - t

ＳＡＭＰＬＥ－５

DEF SEG = &HB800
x = 1: y = 1
t = TIMER
FOR i = 1 TO 10
FOR j = 1 TO 79
ＦＯＲ　ｋ＝０ＴＯ４０００　：　ＮＥＸＴ　　　　　　’ここでＷＡＩＴをかけている。　　　　　　　
LOCATE y, x: PRINT " ";
LOCATE i, j: PRINT "*";
y = i: x = j
NEXT
NEXT
t1 = TIMER
LOCATE 17, 1
PRINT "time": PRINT USING "##.####"; t1 - t

おまけで、今までＱｂａｓｉｃで話をしてきましたが、試しに同様のプログラムを
Ｎ８８互換ＢＡＳＩＣｆｏｒｗｉｎと、筆者の最古のパソコンＦＭ－８（Ｆ－ＢａｓｉｃＶｅｒ２.０）で
試してみます。

（Ｎ８８互換ＢＡＳＩＣｆｏｒＷｉｎ　　　ＦＭ－８＋Ｆ-ＢＡＳＩＣ　用）

10 width 80,20
20 cls
25 x=0:y=0
30 t=val(right$(time$,2))
40 for i=0 to 9
50 for j=0 to 79
60 locate x,y: print " "
70 locate j,i:print "q"
80 x=j:y=i
90 next j
95 next i
100 t1=val(right$(time$,2))
110 if t1<t then t1=t1+60
120 print t1-t

Ｎ８８互換ＢＡＳＩＣｆｏｒＷｉｎは１６ビット用のものを使用しました。（３２ビット用の最新
ヴァージョンはもっと速いと思いますが）。平均２８秒でした。
ＦＭ－８＋Ｆ－ＢａｓｉｃＶｅｒ２.０では平均３５秒でした。
どちらも、ウェイト無しでキャラクタの動きを目でおえました。ＱＢＡＳＩＣと１００倍以上のスピード
差がついています。
ＦＭ－８など使っていた時代は、スピードアップのための工夫というのが、非常に重要でしたが、
ＱＢＡＳＩＣでは、心配無用のようです。

Ｂａｓｉｃ活用研究目次
ＴＯＰPAGE