データの並び替え（大きい順、小さい順など）は、まさしくパソコンにまかせるべき作業です。
人間ならうんざりするような、何千、何万というデータの並び替えを文句も言わず、瞬時に
こなしてくれます。
データの並びかえや、最大値、最小値の検索、順位づけなども、配列を使います。

データの並び替えについては、いろいろな方法が研究されていますが、以下に一番単純な
バブルソートによるデータ並び替え（小さい順）のプログラム例を示します。
バブルソート法というのは、隣同士のデータを順番に比較し、入れ替えていく方法です。
ここでは、小さい順に並べ替えなので、隣同士を比較し、
・前のデータ＜後ろのデータ 　ならそのまま
・前のデータ＞後ろのデータ 　なら入れ替え
という作業を繰り替えしていきます。
Ｎ個のデータがある場合、１回目はＮ−１回隣同士を比較し入れ替えます。これで、一番大きい
データは一番後ろに移動します（一番大きいデータの確定）。一番大きいデータは確定したので、
２回目は、残りのＮ−１個のデータの入れ替えです。今度はＮ−２回隣同士を比較し入れ替えま
す。これで、２番めに大きいデータが、後ろから２番目に確定します。以下、Ｎ−２，Ｎ−３個の
データの入れ替えという作業をくりかえします。Ｎ個のデータの場合、結局Ｎ−１回の作業で、
並べ変えが完了します。

データ４個（５，９，４，３の場合）
１回目のソート　　　　　　　　　　２回目　　　　　　　　３回目
５　−＞５　　　　　　　　　　　　５−＞４　　　　　　　４−＞３　
９　−＞９ −＞４　　　　　　　 ４−＞５−＞３　　　 ３−＞４
４　　　　４ −＞９−＞３　　　 ３　　　３−＞５　　　 ５　
３　　　　　　　　 ３−＞９　　　 ９　　　　　　　　　　　 ９
　　　　　　　　　　９は確定　　　　　　　５が確定　　　　　全部確定

BUBSORT.BAS（N88互換Basic for Win用）
データは９個乱数で発生させています

1 'バブルソート
5 CLS
10 randomize val(right$(time$,2))
15 n=9　　　　　　　　　　　　　　　　 　'データ個数 ここでは９個
20 for i=0 to n
30 a(i)=int(rnd*100): print a(i);　　　'ａ（０）からａ（９）にデータ設定
40 next
50 'バブルソート
60 for i=n to 1 step -1　　　　　　'ソートするデータ個数は１かい毎に減少
70 for j=0 to i-1　　　　　　　　　　'ソートするデータは ０ からｉ−１（＝ｎ−１）番まで
80 if a(j)>a(j+1) then swap a(j),a(j+1)　　'前のデータ＞後ろのデータ　なら入れ替え
90 next j
100 next i
110 print:print "結果ＰＲＩＮＴ"
120 for i=0 to 9
130 print a(i);
140 next
150 print:print "もう1かいやる？(y/n)"
160 q$=input$(1)
170 if q$="y" or q$="Y" then goto 20

2 トランプのシャッフル

トランプもパソコンのゲームでよくありますが、カードの設定とシャッフルも配列を使うと簡単に
できます。

以下のプログラムは、シャッフルしてその結果を表示するものですが、変数等は次のように
設定しています。
０から５２の数値にカードを設定します。設定ルールは以下の通りとします。　　
０ ジョーカー
１ から １３ 　　　　ハート　　１ が ハート １
１４ から ２６　　　ダイヤ　　　１４がダイヤ １
２７ から ３９　　　クラブ
４０から ５２ 　　　スペード
この数値を配列 K() に設定します。K() の添え字はカードが何枚目かを表します。　
（例）
K(3) = 0　　　４枚目（配列は０からはじまるので）のカードがジョーカー
K(34) = 1　　３５枚めのカードが ハート １

変数Q$()は表示用です。
例えば K(11) = 0 の場合 （１２枚めのカードがジョーカー）
Q$(K(11)) は“ジョーカー ”と表示します。

K()の値でカードの種類が判別できるので、K()の値を判定することにより、いろんなトランプ
ゲームが作成できます。また、カードの表示はQ$(K( ))で行えます。

シャッフルは、１ から ５２ までの乱数を発生させ ０番のカードと交換していくというやり方を
とっています。１００回もやればかなり、混ざると思います。

乱数 ５　＝＝＝＞ 乱数 ２　　＝＝＞
Ｋ（０）＝０　　　　　Ｋ（０）＝５　　　　　Ｋ（０）＝２　　　　　
Ｋ（１）＝１　　　　　Ｋ（１）＝１ 　　　　 Ｋ（１）＝１　
Ｋ（２）＝２　　　　　Ｋ（２）＝２　　　　　ｋ（２）＝５
・・・・・・・　　　　　　　・・・・・・・　　　　　・・・・・・・・　
ｋ（５）＝５　　　　　Ｋ（５）＝０　　　　　Ｋ（５）＝０
・・・・・・・・　　　　　　　・・・・・・ 　　　　　・・・・・・・

トランプのカード設定、シャッフルの方法は他にもいろいろありますが、筆者はだいたいこの
方法でやりました。

SHUFFLE.BAS（Ｎ８８互換ＢＡＳＩＣ ｆｏｒ Ｗｉｎ 用）

1 'SHUFFLE
10 dim q$(52),k(52)
20 cls
25 '初期設定
30 q$(0)="Joker***"
40 for i=1 to 13
50 q$(i)="ハート"+str$(i)
60 q$(i+13)="ダイヤ"+str$(i)
70 q$(i+26)="クラブ"+str$(i)
80 q$(i+39)="スペド"+str$(i)
90 next
92 for i=0 to 52
94 q$(i)=left$(q$(i)+" ",9)
96 next
97 for i=0 to 52
98 k(i)=i
99 next
100 'シャッフル
110 randomize val(right$(time$,2))
120 for j=0 to 100
130 i=int(rnd*52)+1
140 swap k(0), k(i)
150 next
155 '結果表示
160 for i=0 to 12
170 for j=0 to 3
180 print q$(k(i*4+j))+" ";
190 next j
195 print
200 next i
210 print q$(52)

ＴＯＰ ＰＡＧＥ >Ｂａｓｉｃ活用研究目次